Briggs Softworks

Code: Select all

function TMainForm.ImportHH(HH: TStringList): integer;
var
  i, j, p, Stage, DBHand, DBRake, DBDealt: integer;
  s, DBTable, DBDate, DBTime, SQL: string;
  DBShare: double;
  Players: TStringList;
  Stmt: TDISQLite3Statement;
begin
  Result := 0;
  Players := TStringList.Create;
  Players.Sorted := True;
  Players.Duplicates := dupIgnore;
  DBHand := 0;
  DBTable := '';
  DBRake := 0;
  Stage := 0;
  for i := 0 to HH.Count - 1 do
  begin
    s := HH[i];
    if Pos('Hand #', s) = 1 then
    begin
      p := Pos('-', s);
      if p = 0 then Continue;
      DBHand := StrToIntDef(Copy(s, 7, p - 7), 0);
      if DBHand = 0 then Continue;
      p := Pos(' - ', s);
      if p > 0 then
      begin
        DBDate := Copy(s, p + 3, 10);
        DBTime := Copy(s, p + 14, 8);
      end else
      begin
        DBDate := '';
        DBTime := '';
      end;
      DBTable := '';
      DBRake := 0;
      Players.Clear;
      Stage := 1;
      Continue;
    end;
    case Stage of
      0: Continue;
      1: if Pos('Game: ', s) = 1 then
         begin
           if Pos('+', s) > 0 then Break; // skip if tournament
           Stage := 2;
         end;
      2: if Pos('Table: ', s) = 1 then
         begin
           DBTable := Copy(s, 8, 99);
           Stage := 3;
         end;
      3: if Pos('** Deck **', s) = 1 then
         begin
           Stage := 0;
           DBDealt := Players.Count;
           if (DBRake = 0) or (DBDealt = 0) then Continue;  // no rake if no flop
           DBShare := DBRake / DBDealt;
           SQL := 'REPLACE INTO Master (Hand, TableName, Date, Time, Rake, Dealt, Share) ' +
                  'VALUES(?, ?, ?, ?, ?, ?, ?);';
           Stmt := RakeDatabase.Prepare16(SQL);
           Stmt.Bind_Int(1, DBHand);
           Stmt.Bind_Str16(2, DBTable);
           Stmt.Bind_Str16(3, DBDate);
           Stmt.Bind_Str16(4, DBTime);
           Stmt.Bind_Int(5, DBRake);
           Stmt.Bind_Int(6, DBDealt);
           Stmt.Bind_Double(7, DBShare);
           Stmt.Step;
           Stmt.Free;
           SQL := 'REPLACE INTO Detail (Hand, Player) VALUES(?, ?);';
           Stmt := RakeDatabase.Prepare16(SQL);
           for j := 0 to Players.Count - 1 do
           begin
             Stmt.Bind_Int(1, DBHand);
             Stmt.Bind_Str16(2, Players[j]);
             Stmt.StepAndReset;
           end;
           Stmt.Free;
           Inc(Result);
         end else
         if Pos('Rake (', s) = 1 then  // multiple rakes if side pots
         begin
           p := Pos(')', s);
           DBRake := DBRake + StrToIntDef(Copy(s, 7, p - 7), 0);
         end else
         begin
           if Pos('"', s) > 0 then Continue;  // skip chat lines
           p := Pos(' posts ', s);
           if p = 0 then p := Pos(' has the dealer button', s);
           if p = 0 then p := Pos(' checks', s);
           if p = 0 then p := Pos(' calls ', s);
           if p = 0 then p := Pos(' bets ', s);
           if p = 0 then p := Pos(' raises ', s);
           if p = 0 then p := Pos(' folds', s);
           if p = 0 then p := Pos(' wins ', s);
           if p = 0 then p := Pos(' refunded ', s);
           if p > 1 then Players.Add(Copy(s, 1, p - 1));
         end;
    end;
  end;
  Players.Free;
end;